cmake_minimum_required(VERSION 3.29)
set(PIM_VERSION "6.7.80")
project(akonadi-calendar-tools VERSION ${PIM_VERSION})

set(KF_MIN_VERSION "6.25.0")
set(QT_REQUIRED_VERSION "6.9.0")
find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
include(ECMInstallIcons)

include(ECMSetupVersion)
include(ECMAddTests)

include(GenerateExportHeader)
include(ECMGenerateHeaders)

include(KDEGitCommitHooks)
include(KDEClangFormat)
file(
    GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES
    *.cpp
    *.h
    *.c
)
if(EXISTS "${PROJECT_SOURCE_DIR}/.git/")
    set(GIT_SOURCE_TARBALL TRUE)
endif()

if(GIT_SOURCE_TARBALL)
    set(PRE_COMMIT_INSTALLED FALSE)
    include(KDEGitCommitHooks)
    include(KDEClangFormat)
    kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
    if(${CMAKE_SOURCE_DIR} STREQUAL ${PROJECT_SOURCE_DIR})
        if(EXISTS "${PROJECT_SOURCE_DIR}/.git/hooks/pre-commit")
            file(READ "${PROJECT_SOURCE_DIR}/.git/hooks/pre-commit" FILE_CONTENTS)
            string(
                FIND "${FILE_CONTENTS}"
                "File generated by pre-commit"
                INDEX
            )
            if(${INDEX} GREATER_EQUAL 0)
                set(PRE_COMMIT_INSTALLED TRUE)
            endif()
        endif()
    endif()
    if(NOT ${PRE_COMMIT_INSTALLED})
        function(install_hook executable hook_name)
            message(
                STATUS
                "This module has ${hook_name} support. ${hook_name} binary was found. Installing ${hook_name} hook"
            )
            execute_process(
                COMMAND
                    "${executable}" install -f
                ERROR_QUIET
                RESULT_VARIABLE _precommitresult
                WORKING_DIRECTORY "${PROJECT_SOURCE_DIR}"
            )
            if(_precommitresult EQUAL 0)
                message(STATUS "${hook_name} installed.")
            else()
                message(
                    WARNING
                    "Error during installing ${hook_name} hook: ${executable} project source dir ${PROJECT_SOURCE_DIR}"
                )
            endif()
        endfunction()
        find_program(PREK_EXECUTABLE prek)
        if(PREK_EXECUTABLE)
            install_hook(${PREK_EXECUTABLE} "Prek")
        else()
            find_program(PRE_COMMIT_EXECUTABLE pre-commit)
            if(PRE_COMMIT_EXECUTABLE)
                install_hook(${PRE_COMMIT_EXECUTABLE} "pre-commit")
            else()
                message(WARNING "This module has pre-commit support. pre-commit binary was not found.")
            endif()
        endif()
    endif()
endif()

include(KDEInstallDirs)
include(KDECMakeSettings)
include(KDECompilerSettings NO_POLICY_SCOPE)
include(ECMAddAppIcon)
include(ECMQtDeclareLoggingCategory)
include(ECMDeprecationSettings)
include(ECMFeatureSummary)
# Do NOT add quote
set(KDEPIM_DEV_VERSION beta)

# add an extra space
if(DEFINED KDEPIM_DEV_VERSION)
    set(KDEPIM_DEV_VERSION " ${KDEPIM_DEV_VERSION}")
endif()

set(KDEPIM_VERSION "${PIM_VERSION}${KDEPIM_DEV_VERSION}")

set(AKONADICALENDAR_LIB_VERSION "6.7.80")
set(AKONADI_VERSION "6.7.80")
set(CALENDARSUPPORT_LIB_VERSION "6.7.80")
set(KDEPIM_LIB_VERSION "${PIM_VERSION}")
set(KDEPIM_LIB_SOVERSION "6")

find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Widgets)

# Find KF6 package
find_package(KF6I18n ${KF_MIN_VERSION} REQUIRED)
find_package(KF6DocTools ${KF_MIN_VERSION})
set_package_properties(
    KF6DocTools
    PROPERTIES
        DESCRIPTION
            "Tools to generate documentation"
        TYPE
            OPTIONAL
)

# Find KdepimLibs Package
find_package(KPim6Akonadi ${AKONADI_VERSION} CONFIG REQUIRED)
find_package(KF6CalendarCore ${KF_MIN_VERSION} CONFIG REQUIRED)
find_package(KPim6AkonadiCalendar ${AKONADICALENDAR_LIB_VERSION} CONFIG REQUIRED)
find_package(KPim6CalendarSupport ${CALENDARSUPPORT_LIB_VERSION} CONFIG REQUIRED)

include_directories(
    ${akonadi-calendar-tools_SOURCE_DIR}
    ${akonadi-calendar-tools_BINARY_DIR}
)

configure_file(console-version.h.in ${CMAKE_CURRENT_BINARY_DIR}/console-version.h @ONLY)

add_definitions(-DQT_NO_CONTEXTLESS_CONNECT)
if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
    # Not setting for GNU due to too many warnings related to private members of base classes or around lambdas
    # see e.g. https://gcc.gnu.org/bugzilla/show_bug.cgi?id=56556 or https://gcc.gnu.org/bugzilla/show_bug.cgi?id=79328
    string(APPEND CMAKE_CXX_FLAGS " -Wshadow")
endif()
ecm_set_disabled_deprecation_versions(QT 6.8.1 KF 6.28.0)

add_definitions(-DQT_NO_EMIT)
option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)

set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
if(USE_UNITY_CMAKE_SUPPORT)
    set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
    add_definitions(-DCOMPILE_WITH_UNITY_CMAKE_SUPPORT)
endif()

add_subdirectory(calendarjanitor)
add_subdirectory(konsolekalendar)

ecm_qt_install_logging_categories(
        EXPORT AKONADICALENDARTOOLS
        FILE console.categories
        DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
)

if(GIT_SOURCE_TARBALL)
    if(DEFINED kde_configure_git_pre_commit_hook)
        kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
    endif()
endif()

ki18n_install(po)
if(KF6DocTools_FOUND)
    kdoctools_install(po)
    add_subdirectory(doc)
endif()

ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
