Inhoud

# GEMIDDELDEN.ALS-functie

Geeft het rekenkundig gemiddelde van alle cellen in een bereik die voldoen aan meerdere opgegeven criteria . De GEMIDDELDEN.ALS-functie telt alle resultaten die overeenkomen met de logische tests op en deelt dit totaal door het aantal geselecteerde waarden.

Deze functie is beschikbaar sinds LibreOffice 4.0.

### Syntaxis

GEMIDDELDEN.ALS(Sombereik; Breik 1; Criteria 1[; Bereik 2; Criteria 2][; … ; [Bereik 127; Criteria 127]])

Gemiddeld bereik – vereist argument. Het is een reeks cellen, een naam van een benoemd bereik of een label van een kolom of een rij met waarden, voor de berekening van het gemiddelde.

Bereik1 – vereist argument. Het is een celbereik, een naam van een benoemd bereik of een label van een kolom of rij waarop het overeenkomstige criterium moet worden toegepast.

Criterium1: Een criterium is een tekstuele expressie die is berekend op basis van een enkele celreferentie, formule, getal of tekst. Het wordt gebruikt in vergelijkingen met celinhoud.

Een verwijzing naar een lege cel wordt geïnterpreteerd als de numerieke waarde 0.

Een overeenkomende uitdrukking kan zijn:

- Een getal of logische waarde. Een overeenkomende celinhoud is gelijk aan het getal of de logische waarde.

- Een waarde die begint met een vergelijker (, <=, =, >, >=, <>).

  Voor =: als de waarde leeg is, komt deze overeen met lege cellen.

  Voor <> geldt dat als de waarde leeg is, deze overeenkomt met niet-lege cellen.

  Als de waarde voor <> niet leeg is, komt deze overeen met alle celinhoud behalve de waarde, inclusief lege cellen.

  Opmerking: "=0" komt niet overeen met lege cellen.

  Voor = en <>, als de waarde niet leeg is en niet kan worden geïnterpreteerd als een getaltype of een van de subtypen ervan en de eigenschap Zoekcriteria = en <> moeten op hele cellen van toepassing zijn is aangevinkt, de vergelijking vindt plaats met de volledige celinhoud, als niet aangevinkt, wordt er vergeleken met elk subgedeelte van het veld dat aan de criteria voldoet. Voor = en <>, als de waarde niet leeg is en niet kan worden geïnterpreteerd als een getaltype of als een van de subtypes ervan van toepassing is.

- Andere tekstwaarde. Als de eigenschap Zoekcriteria = en <> moeten gelden voor hele cellen waar is , is de vergelijking met de gehele celinhoud. Als deze niet waar is, wordt er met elk subdeel van het veld vergeleken dat aan de criteria voldoet. De expressie kan tekst, getallen, reguliere expressies of jokertekens bevatten (indien ingeschakeld in berekeningsopties).

Bereik 2 – Optioneel. Bereik 2 en alle volgende hebben dezelfde betekenis als Bereik 1.

Criterium 2 – Optioneel. Criterium 2 en alle volgende betekenen hetzelfde als Criterium.

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" invoeren, bijvoorbeeld om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere expressie is, moet u elk metateken of operator van een reguliere expressie laten voorafgaan door een "\"-teken, of de tekst in \Q...\E insluiten. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in LibreOffice - Voorkeuren Extra - Opties - LibreOffice Calc - Berekenen .

Wanneer u functies gebruikt waarbij een of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een landinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".

Gemiddeld bereik enBereik 1, Bereik 2... moeten hetzelfde formaat hebben, anders geeft de functie fout:502 - Ongeldig argument.

De logische relatie tussen criteria kan worden gedefinieerd als logische EN (conjunctie). Met andere woorden, als en alleen als aan alle gegeven criteria is voldaan, wordt een waarde uit de overeenkomstige cel van de gegeven Gemiddeld bereik in de berekening meegenomen.

De functie kan maximaal 255 argumenten bevatten, wat betekent dat u 127 bereiken en voorwaarden kunt opgeven.

Als een cel WAAR bevat, wordt het behandeld als 1, als een cel ONWAAR bevat als 0 (nul).

### Voorbeelden

Overweeg de volgende tabel

| A | B | C
1 | Productnaam | Sales | Revenue
2 | penhouder | 20 | 65
3 | pen | 35 | 85
4 | kladblok | 20 | 190
5 | boek | 17 | 180
6 | etui | niet | niet

In alle onderstaande voorbeelden, bevatten bereiken voor berekening de rij # 6, die genegeerd wordt omdat deze tekst bevat.

#### Eenvoudig gebruik

=GEMIDDELDEN.ALS(B2:B6;B2:B6;">=20")

Berekent het gemiddelde van de waarden van het bereik B2:B6 die groter of gelijk zijn aan 20. Dit geeft 25, omdat de vijfde rij niet aan het criterium voldoet.

=GEMIDDELDEN.ALS(C2:C6;B2:B6;">=20";C2:C6;">70")

Berekent het gemiddelde van de waarden van het bereik C2:C6, die groter zijn dan 70 en overeenkomen met cellen van B2:B6 met waarden groter dan of gelijk aan 20. Dit geeft 137,5, omdat de tweede en vijfde rij niet voldoen aan tenminste één criterium.

#### Met behulp van reguliere expressies en geneste functies

=GEMIDDELDEN.ALS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Berekent het gemiddelde van de waarden van het bereik C2:C6, die overeenkomen met alle waarden van het bereik B2 B6 behalve de kleinste en de grootste. Dit geeft 127,5, omdat de derde en vijfde rij niet voldoen aan tenminste één criterium.

=GEMIDDELDEN.ALS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Berekent het gemiddelde van de waarden van het bereik C2:C6, die overeenkomen met alle cellen van het bereik A2: A6, die beginnen met "pen" en alle cellen van het bereik B2:B6 behalve de grootste. Dit geeft 65, want alleen tweede rij voldoet aan alle criteria.

#### Refereer naar een cel als een criterium

Als u een criterium gemakkelijk moet kunnen veranderen, kunt u dit in een aparte cel opvoeren en gebruik maken van een verwijzing naar deze cel in de voorwaarde van de GEMIDDELDE.ALS-functie. De bovenstaande functie kan bijvoorbeeld als volgt worden herschreven:

=GEMIDDELDEN.ALS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Als E2 = pen, geeft de functie 65, omdat de koppeling naar de cel wordt vervangen met de inhoud ervan.

Deze functie maakt deel uit van het Open Document Format voor Office Applications (OpenDocument) standaard versie 1.2. (ISO/IEC 26300: 2-2015)

Verwante onderwerpen

Wiki-pagina GEMIDDELDEN.ALS.

GEMIDDELDE, GEMIDDELDEA, GEM.DEVIATIE, GEMIDDELDE.ALS-functie

AANTALLEN.ALS, MIN.ALS.VOORWAARDEN, MAX.ALS, GEMIDDELDEN.ALS, SOMMEN.ALS

Lijst met reguliere expressies